WSH (Windows Script Host) を使ったユーザ環境変数設定方法

WSH (Windows Script Host) を使ったユーザ環境変数設定方法
ora_instantclientのパスを通す

前提
　USER環境へ　
　　PATH=C:\ora_instantclient
　　NLS_LANG=JAPANESE_JAPAN.JA16SJISTILDE
　を登録する。

ora_instantclient環境変数設定.vbsへ以下コードを保存して実行する。
すでに存在していれば登録しません。

　※ＧＵＩでやるなら、マイコンピュータ右クリック→プロパティ→詳細タブ→環境変数

'****************************************************
'*
'* ORACE INSTANT CLIENT 用 USER 環境変数設定
'*　　　設定内容
'* 　　PATH=C:\ora_instantclient
'*　　　　　　　　　　※ora_instantclientフォルダの場所によって変更する。
'* 　　NLS_LANG=JAPANESE_JAPAN.JA16SJISTILDE
'*
'* システム環境変数に設定する場合
'* 　　　　　Set WshEnvironment = WshShell.Environment("USER")
'* 　　　　※"USER" → "SYSTEM" に変更する。
'*
'****************************************************

if msgbox ("ORACE INSTANT CLIENT　環境変数設定" & vbCR & vbCR & _
"PATH=C:\ora_instantclient " & vbCR & _
"NLS_LANG=JAPANESE_JAPAN.JA16SJISTILDE",vbYesNo + vbQuestion) <> vbYes then
'終了
WScript.Quit
end if

'環境変数設定
Set WshShell = CreateObject("WScript.Shell")
Set WshEnvironment = WshShell.Environment("USER")

'PATHの設定
W_PATH = WshEnvironment.Item("PATH")

If W_PATH = "" Then
WshEnvironment.Item("PATH") = "C:\ora_instantclient"
Else
if instr(W_PATH,"ora_instantclient")<=0 then
WshEnvironment.Item("PATH") = W_PATH & ";" & "C:\ora_instantclient"
else
msgbox "PATHが既に存在します、確認してください。" & vbCR & vbCR & _
"PATHの登録はしません。",vbCritical
end if
End If

'NLS_LANGの登録
if WshEnvironment.Item("NLS_LANG")<>"" Then
msgbox "NLS_LANGの変数が既に存在します、確認してください。" & vbCR & vbCR & _
"NLS_LANGの登録はしません。",vbCritical
else
WshEnvironment.Item("NLS_LANG") = "JAPANESE_JAPAN.JA16SJISTILDE"
end if

msgbox "登録　終了"