「晴れのちおおさわぎ」IPL分析（後半）

後半です。
「晴れのちおおさわぎ」IPL分析（前半）でもそうですが，Tabキーで設けた落差がHTMLには反映されないんですかね。
読みにくいですが，読む気のある人にとってはさほどの障害にはならんでしょう。

B000:0050からの続き。

;ディスク読み出し
B000:0052 E8F100 CALL 0146H ;ディスク読み出しサブルーチン呼出し~01A5H +++++++++++++++++

;ディスク読み出しサブルーチン
;(UNDOCUMENTED 9801/9821 小高輝真・河野健著 株式会社インプレス発行 '94/03/21,P.181~)
;（トランジスタ技術SPECIAL No.45 CQ出版社 '94/05/01 P.25）
;（PC-9801プログラマーズBible第２版，東京理科大学EIC編，技術評論社刊 '96/08/05 P.264~,P.276~)
B000:0146 06 PUSH ES ;ES退避
B000:0147 2BC0 SUB AX,AX ;AX=0000H
B000:0149 8EC0 MOV ES,AX ;ES=0000H
B000:014B 26A08405 MOV AL,ES:[0584H] ;disk_boot ALにブートドライブ情報を代入。
;0000H:0584HにはOSのブートしたディスク装置の情報が書かれている。
;0584Hの数値は下位4ビットがUA(ユニット番号，Unit Adress)，
; 　　 上位4ビットがDA(デバイスタイプ識別コード，
; Drive Adress)。
;ex. 90H=1001 0000
; UA 0000 ドライブ1
; 0001 ドライブ2
; 0010 ドライブ3
; 0011 ドライブ4
;DA アクセスモード　640KB 0xxx
; 1MB/HDD 1xxx
; ハードディスク x000
; 1MBインターフェース x001
; 640KBインターフェース x111
B000:014F B456 MOV AH,56H ;DISK BIOS(シングルトラック(bit7=0),
;倍密度MFM(bit6=1),8回リトライ(bit5=0),
;シーク動作する(bit4=1))，データ読み出し。
B000:0151 8BF8 MOV DI,AX ;DI=56UAH DISK BIOS格納AX退避
B000:0153 B86000 MOV AX,0060H ;
B000:0156 8EC0 MOV ES,AX ;ES=0060H 読み出すセグメント
B000:0158 2BED SUB BP,BP ;BP=0000H 読み出すオフセット
;(データバッファ領域先頭アドレス,ES:BP=0060H:0000H)
B000:015A BB0004 MOV BX,0400H ;BX=0400H 読み込むバイト数(1024バイト)，データ長(DTL)
B000:015D B90003 MOV CX,0300H ;CX=0300H CH(N)=03H,CL(C)=00H(シリンダNo.0,セクタ長1024バイト(2の(3+7)乗))

;FATセクタ読み出し
B000:0160 BA0200 MOV DX,0002H ;DX=0002H DH(H)=00H,DL(R)=02H(ヘッドNo.0,セクタNo.2)FAT読み出し
B000:0163 E85EFF CALL 00C4H ;ディスク読み出しサブルーチン２呼出し ~00DD++++++++++++++++++

;ディスク読み出しサブルーチン２（正常に読み出せるまで５回トライ，成功すればCF=0,AX=0000H，
;失敗すればCF=1,AX=0FFFFH）
B000:00C4 BE0500 MOV SI,0005H ;カウンタを5回にセットした。
B000:00C7 8BC7 MOV AX,DI ;AXを復帰(0151Hで退避させたDISK BIOS格納AX）。
;MOV AH,56H（データの読み出し），
;MOV AL,90(ドライブ1)
; or91(ドライブ2)
B000:00C9 CD1B INT 1BH ;正常に読み出せればAH=00，CF=0
;Drive Not ReadyならAH=60，CF=1
B000:00CB 730E JNB 00DBH ;正常に読めた(CF=0)とき，00DBHへ。-----------------------------------
B000:00CD 8BC7 MOV AX,DI ;正常に読めなかったとき(CF=1)，再度AXを復帰。00C7のやり直し。
B000:00CF B407 MOV AH,07H ;DISK BIOS RECALIBRATE
B000:00D1 CD1B INT 1BH ;ヘッドのシリンダ0への移動
B000:00D3 4E DEC SI ;カウンタを1減らす。
B000:00D4 75F1 JNE 00C7H ;ZF=0（カウンタ残あり）のとき，00C7Hへ。-----------------------------
B000:00D6 B8FFFF MOV AX,0FFFFH ;ZF=1（正常に読めず，カウンタ残なし）ならAX=0FFFFHにして復帰。
B000:00D9 EB02 JMP 00DDH ;--------------------------------------------------------------------
B000:00DB 2BC0 SUB AX,AX ;AXを0000Hにして復帰(ZF=1)。
B000:00DD C3 RET ;====================================================================

B000:0166 7305 JNB 016DH ;正常に読み出して帰れば(CF=0)016DHへ。AX=0000Hで復帰。-------
B000:0168 BA3802 MOV DX,0238H ;94 07 'データを読み込むことができません。'00 FF FF 00
B000:016B EB37 JMP 01A4H ;01A4H(POP ESしてRET)。0055Hへ。-----------------------------
B000:016D 268A4600 MOV AL,ES:[BP+00H] ;FAT先頭データ(0FFH)をALに代入。
B000:0171 FEC0 INC AL ;0FFH+1=00H
B000:0173 7405 JE 017AH ;ZF=1なので017AHへ。-----------------------------------------
B000:0175 BABC02 MOV DX,02BCH ;94 07 'ディスクの形式が違います。'00 FF FF
B000:0178 EB2A JMP 01A4H ;01A4Hに飛んでPOP ESしてRET。--------------------------------

;ディレクトリエントリ（ルートディレクトリ）セクタ読み出し
B000:017A B204 MOV DL,04H ;DL=04H。C=0,H=0,R=04,N=03
;トラック0，ヘッド0，第4セクタ(ディレクトリエントリ)，レングス3を読む。
;AX=0000H
B000:017C E845FF CALL 00C4H ;ディスク読み出しサブルーチン２呼出し ~00DDH ++++++++++++++++
;CALL後省略

B000:017F 72E7 JB 0168H ;CF=1(正常に読めなかったとき)なら，0168Hへ。AX=0FFFFH -------
B000:0181 8BDD MOV BX,BP ;BX=0000H(BP=0000H,0158H以降変動なし)
B000:0183 B92000 MOV CX,0020H ;カウンタに0020Hをセット。
B000:0186 268A07 MOV AL,ES:[BX] ;第４セクタ先頭データ(0CAH)をALに代入。
B000:0189 3CE5 CMP AL,0E5H ;0CAHと0E5Hを比較。ZF=0
B000:018B 740D JE 019AH ;ZF=1なら019AHへジャンプ。(無限ループ)-----------------------
B000:018D 0AC0 OR AL,AL ;AL=0CAH
B000:018F 74E4 JE 0175H ;ZF=1なら0175Hへ。-------------------------------------------
B000:0191 268B470A MOV AX,ES:[BX+0AH] ;第４セクタ先頭から000AHの中身2バイトを2941HをAXに代入。
;Bディスクなら2942H
B000:0195 80FC29 CMP AH,29H ;AH=29Hと29Hを比較。
B000:0198 7404 JE 019EH ;ZF=1なので019EHへ。 ----------------------------------------
B000:019A E2EA LOOP 0186H ;0186Hへのループを32回。
B000:019C EBD7 JMP 0175H ;0175Hへ。---------------------------------------------------
B000:019E 2C41 SUB AL,41H ;AL=41Hから41Hを減ずる。AL=00H
;Bディスクならディスク違い。AL=01H
B000:01A0 98 CBW ;バイト(AL)からワード(AX)への変換。
;ビット7をAHの全てのビットにコピーする。AX=0000H
;BディスクならAX=0001H
B000:01A1 BE3802 MOV SI,0238H ;94 07 'データを読み込むことができません。'00 FF FF 00
B000:01A4 07 POP ES
B000:01A5 C3 RET ;0055Hへ。 ==================================================

;ディスク読み出し結果分岐ルーチン
B000:0055 85C0 TEST AX,AX ;ZF=1(AX=0000Hのとき)
B000:0057 7513 JNE 006CH ;ZF=0(AX=FFFFH，正常に読めなかった）なら，006CHへ。--------

;############################################################################################
（ここからエラー表示）
0168Hから来た（第２または第４セクタを読み出せなかった）とき ;94 07 'データを読み込むことができません。'00 FF FF 00
0175Hから来た（FATデータ不一致）とき ;94 07 'ディスクの形式が違います。'00 FF FF
01A5Hから来たが，ディスク違いの場合
B000:006C 2E00067A02 ADD CS:[027AH],AL ;半角Aと半角Bの文字コード差分を「Ａ」の文字コードに加算する。
B000:0071 BE6002 MOV SI,0260H ;'このディスクは 「Ｎｏ．Ａ（+文字コード差分）」 です。'
B000:0074 EB06 JMP 007CH ;007CHへ。-----------------------------------------------------------
B000:007C E89400 CALL 0113H ;文字列表示サブルーチン呼出し~0119h +++++++++++++++++++++++++++++++++
（以下省略，ハイレゾモードエラー表示部分参照）
（エラー表示終了）
;#############################################################################################

B000:0059 E83600 CALL 0092H ;第５セクタ以下読み出しルーチンへ~00C3H +++++++++++++++++++

;第５セクタ以降が正常に読み出せるか（５８セクタ分）？
B000:0092 06 PUSH ES ;ES退避。
B000:0093 B86000 MOV AX,0060H
B000:0096 8EC0 MOV ES,AX ;ES=0060H 読み出すセグメント
B000:0098 BB0004 MOV BX,0400H ;BX=0400H 読み出すバイト数，データ長(DTL)
B000:009B B90003 MOV CX,0300H ;CX=0300H CH(N)=03H,CL(C)=00H
B000:009E BA0500 MOV DX,0005H ;DX=0005H DH(H)=00H,DL(R)=05H セクタ５読み出し
B000:00A1 E82000 CALL 00C4H ;ディスク読み出しサブルーチン２呼出し ~00DDH ++++++++++++++++
;CALL後省略

B000:00A4 85C0 TEST AX,AX ;ZF=1(正常に読み出されたとき)
B000:00A6 751A JNE 00C2H ;ZF=0（正常に読み出せなかったとき）なら00C2Hへ。POP ESしてRET。------
B000:00A8 03EB ADD BP,BX ;BP+0400H
B000:00AA 81FD00E8 CMP BP,0E800H ;BPと0E800Hを比較(E800H/0400H=3Aなので58セクタ分読む意味か。)。
B000:00AE 7312 JNB 00C2H ;CF=0(BP>0E800H)なら，00C2Hへ。POP ESしてRET。-----------------------
B000:00B0 FEC2 INC DL ;読み出しセクタ番号を1増やす。
B000:00B2 80FA08 CMP DL,08H ;セクタ番号8か？
B000:00B5 76EA JBE 00A1H ;CF=1またはZF=1のとき(DL<=8)，00A1Hにジャンプ。----------------------
B000:00B7 B201 MOV DL,01H ;セクタ番号8まで来たので読み取りセクタを1に。
B000:00B9 80F601 XOR DH,01H ;ヘッド番号を1に。
B000:00BC 75E3 JNE 00A1H ;ZF=0（既にヘッド番号が1）のとき，00A1Hへジャンプ。------------------
B000:00BE FEC1 INC CL ;シリンダ番号を増やす。
B000:00C0 EBDF JMP 00A1H ;--------------------------------------------------------------------
B000:00C2 07 POP ES ;ES復帰。
B000:00C3 C3 RET ;====================================================================

B000:005C 85C0 TEST AX,AX ;ZF=1
B000:005E 7516 JNE 0076H ;ZF=0（正常に読み出せなかった）のとき，0076Hへ。-----------------------------------------------

;##############################################################################################
（ここからエラー表示）
B000:0076 EB04 JMPS 007CH ;007CHへ。「データを読み込むことができません。」を表示して異常終了。
;SIは01A1Hで積んできた
B000:007C E89400 CALL 0113H ;文字列表示サブルーチン呼出し~0119h +++++++++++++++++++++++++++++++++
（以下省略，エラー表示終了）
;##############################################################################################

B000:0060 B00E MOV AL,0EH ;DISP ENABLE 画面表示OFF テキスト・グラフィックとも
B000:0062 E668 OUT 68H,AL ;http://www.webtech.co.jp/company/doc/undocumented_mem/io_disp.txt

;GOAL
B000:0064 EA00006000 JMP 0060H, 0000H ;データバッファ先頭領域（第５セクタ以下格納）へ。----------------------------------
B000:0069 90 NOP

<<著作権に関して>>
本記事に引用している全てのソフトの名称・画像の著作権・その他権利は、制作、販売されたソフトハウス、メーカー、または作者様に帰属します。本サイトでの上記著作権物扱いは、著作権など各権利関係を侵害することが目的ではありません。問題などある場合は、メール(ｇｅｋｉｇａｎｇａｒあっとｍａｉｌ．ｇｏｏ．ｎｅ．ｊｐ)にてその旨お知らせください。