算額（その967）

算額（その967）

一七 大里郡岡部村岡 稲荷社 文化13年(1816)

埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.

正方形内に斜線を 2 本引き，区画された領域に甲円，乙円を 2 個ずつ入れる。正方形の一辺の長さが 72 寸，甲円の直径が 32 寸のとき，乙円の直径はいかほどか。

正方形の一辺の長さを 2a
斜線と正方形の一辺の交点座標を (a, b)
甲円の半径と中心座標を r1, (0, a - r1)
乙円の半径と中心座標を r2, (a - r2, 0)
とおき，以下の連立方程式を解く。

include("julia-source.txt");

using SymPy
@syms a::positive, b::positive,
     r1::positive, r2::positive
eq1 = dist2(0, 0, a, b, 0, a - r1, r1)
eq2 = dist2(0, 0, a, b, a - r2, 0, r2);
(r2, b) = solve([eq1, eq2], (r2, b))[1];
r2 |> simplify |> println
b  |> simplify |> println

   (a^(3/2)*sqrt(a - 2*r1)*(a - r1) + a^2*(-a + 2*r1))/r1^2
   a^(3/2)*sqrt(a - 2*r1)/r1

正方形の一辺の長さが 72 寸，甲円の直径が 32 寸のとき，乙円の直径は 27 寸である。

a = 72/2
r1 = 32/2
r2 = (a^(3/2)*sqrt(a - 2*r1)*(a - r1) + a^2*(-a + 2*r1))/r1^2
2r2

   27.0

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   (a, r1) = (72, 32) ./ 2
   s = a - 2*r1
   t = a^(3/2)*sqrt(s)
   r2 = (t*(a - r1) - a^2*s)/r1^2
   b = t/r1
   @printf("正方形の一辺の長さが %g，甲円の直径が %g のとき，乙円の直径は %g である。\n", 2a, 2r1, 2r2)
   plot([a, a, -a, -a, a], [-a, a, a, -a, -a], color=:blue, lw=0.5)
   circle22(0, a - r1, r1)
   circle2(a - r2, 0, r2, :green)
   segment(-a, -b, a, b, :magenta)
   segment(-a, b, a, -b, :magenta)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(0, a - r1, "甲円:r1,(0,a-r1)", :red, :center, delta=-delta/2)
       point(a - r2, 0, "乙円:r2,(a-r2, 0)", :green, :center, delta=-delta/2)
       point(0, a, " a", :blue, :left, :bottom, delta=delta/2)
       point(a, 0, " a", :blue, :left, :bottom, delta=delta/2)
       point(a, b, "(a,b) ", :blue, :right, :bottom, delta=delta/2)
   end
end;

算額（その966）

算額（その966）

一七 大里郡岡部村岡 稲荷社 文化13年(1816)

埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.

直角三角形の中に大小の正三角形と甲円，乙円が入っている。乙円の直径が 153 寸のとき，甲円の直径はいかほどか。

大きい正三角形の一辺の長さを a
甲円の半径と中心座標を r1, (x1, r1)
乙円の半径と中心座標を r2, (r2, y2)
とする。

乙円，甲円が入っている二等辺三角形の相似比が 1:√3 であることは関係式を少し書き下せばわかり，甲円の直径も乙円の直径の √3 倍であることが導ける。

ここでは，図を各パラメータを全て求めるため，以下の連立方程式を解く。
SymPy の能力的に一度に解けないので，逐次解いてゆく。

include("julia-source.txt");

using SymPy
@syms a::positive, r1::positive, x1::positive,
     r2::positive, y2::positive
@syms a, r1, x1, r2, y2
eq1 = dist2(0, 0, a/2, √Sym(3)a/2, r2, y2, r2)
eq2 = dist2(a, 0, a/2, √Sym(3)a/2, x1, r1, r1)
eq3 = dist2(0, a/√Sym(3), a/2, √Sym(3)a/2, r2, y2, r2)
eq4 = dist2(2a, 0, a/2, √Sym(3)a/2, x1, r1, r1);
# res = solve([eq1, eq2, eq3, eq4], (r1, x1, y2, a))

y2 を求める。

ans_y2 = solve(eq1, y2)[2]
ans_y2 |> println

   r2*(sqrt(3) + 2)

eq3 に y2 を代入し，a を求める。

eq3 = eq3(y2 => ans_y2) |> simplify;

ans_a = solve(eq3, a)[2]
ans_a |> println

   2*r2*(sqrt(3) + 2)

eq2, eq4 に a を代入し，eq2 から x1 を求める。

eq2 = eq2(a => ans_a) |> simplify;
eq4 = eq4(a => ans_a) |> simplify;

ans_x1 = solve(eq2, x1)[2]
ans_x1 |> println

   sqrt(3)*r1/3 + 2*sqrt(3)*r2 + 4*r2

eq4 に x1 を代入すれば r1, r2 だけを含む式になるので, r1 を求める（r2 を含む式になる）。

eq4 = eq4(x1 => ans_x1) |> simplify
eq4 |> println

   r1^2/3 - 8*sqrt(3)*r1*r2/3 - 4*r1*r2 + 4*sqrt(3)*r2^2 + 7*r2^2

ans_r1 = solve(eq4, r1)[2] |> sympy.sqrtdenest |> simplify
ans_r1 |> println

   sqrt(3)*r2

既知の r2 により r1 が求まったので，順次遡って以下のパラメータを得る。
   y2 = r2*(√3 + 2)
   a = 2y2
   r1 = √3r2
   x1 = √3r1/3 + a

甲円の半径 r1 は乙円の半径 r2 の √3 倍である。
乙円の直径が 153 寸のとき，甲円の直径は 153√3 = 265.00377355803823 寸である。

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   r2 = 153/2
   y2 = r2*(√3 + 2)
   a = 2y2
   r1 = √3r2
   x1 = √3r1/3 + a
   @printf("乙円の直径が %g のとき，甲円の直径は %g である。\n", 2r2, 2r1)
   @printf("r2 = %g;  r1 = %g;  x1 = %g;  y2 = %g;  a = %g\n", r2, r1, x1, y2, a)
   plot([0, 2a, 0, 0], [0, 0, 2a/√3, 0], color=:blue, lw=0.5)
   circle(x1, r1, r1)
   circle(r2, y2, r2, :green)
   segment(0, a/√3, a/2, √3a/2, :magenta)
   segment(0, 0, a/2, √3a/2, :magenta)
   segment(a, 0, a/2, √3a/2, :magenta)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(x1, r1, "甲円:r1\n(x1,r1)", :red, :center, delta=-delta)
       point(r2, y2, " 乙円:r2,(r2,y2)", :green, :left, :vcenter)
       point(a, 0, "a  ", :magenta, :right, :bottom, delta=delta)
       point(a/2, √3a/2, "(a/2,√3a/2)", :magenta, :left, :bottom, delta=delta)
   end
end;

算額（その965）

算額（その965）

一七 大里郡岡部村岡 稲荷社 文化13年(1816)

埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.

長方形の中に斜線，大円，小円を入れる。長方形の長辺，短辺が 6 寸，2 寸のとき，小円の直径はいかほどか。

長方形の長辺，短辺を 2a, 2b，斜線と長辺の交点座標を (c, b), (c, -b)
大円の半径と中心座標を r1, (0, 0); r1 = b
小円の半径と中心座標を r2, (a - r2, 0)
とおき，以下の連立方程式を解く。

include("julia-source.txt");

using SymPy
@syms a::positive, b::positive, c::positive,
     r1::positive, r2::positive
r1 = b
eq1 = dist2(a, -b, c, b, a - r2, 0, r2)
eq2 = dist2(a, -b, c, b, 0, 0, r1);
res = solve([eq1, eq2], (r2, c))[2]

   ((a*b - b^2)/(a + b), b^2/a)

小円の直径は 2b*(a - b)/(a + b) である。
長辺 a = 6/2 寸，b = 2/2 寸のとき，小円の直径は 1 寸である。

a = 6/2
b = 2/2
2b*(a - b)/(a + b)

   1.0

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   (a, b) = (6, 2) ./ 2
   (r2, c) = ((a*b - b^2)/(a + b), b^2/a)
   r1 = b
   plot([a, a, -a, -a, a], [-b, b, b, -b, -b], color=:blue, lw=0.5)
   circle(0, 0, r1)
   circle2(a - r2, 0, r2, :magenta)
   segment(a, -b, c, b, :green)
   segment(a, b, c, -b, :green)
   segment(-a, -b, -c, b, :green)
   segment(-a, b, -c, -b, :green)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(c, b, "(c,b)", :green, :center, :bottom, delta=2delta)
       point(a, b, "(a,b)", :green, :center, :bottom, delta=2delta)
       point(0, 0, "大円:r1,(0,0)", :red, :center, delta=-2delta)
       point(a - r2, 0, "小円:r2\n(a-r2,0)", :magenta, :center, :bottom, delta=delta)
   end
end;

算額（その964）

算額（その964）

一七 大里郡岡部村岡 稲荷社 文化13年(1816)

埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.

外円の中に 6 個の正方形を入れる。それぞれの正方形の 2 つの頂点は外円の周上にあり，残りの 2 つの頂点は隣の正方形の頂点を共有する。正方形の一辺の長さが 22 寸のとき，外円の直径はいかほどか。

正方形の一辺の長さを a
外円の半径と中心座標を R, (0, 0)
とおき以下の方程式を解く。

include("julia-source.txt");

using SymPy
@syms a::positive, R::positive
eq = (a/2)^2 + (a + a√Sym(3)/2)^2 - R^2
res = solve(eq, R)[1]
res |> println
res(a => 22).evalf() |> println

   a*sqrt(sqrt(3) + 2)
   42.5007363567190

外円の半径 R は正方形の一辺の長さ a の √(√3 + 2) 倍である。
正方形の一辺の長さが 22 寸のとき，外円の半径は 42.5007363567190 寸（直径は 85.001472713438 寸）である。

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   a = 22
   R = a*sqrt(sqrt(3) + 2)
   @printf("正方形の一辺が %g のとき，外円の直径は %g\n", a, 2R)
   plot()
   circle(0, 0, R)
   circle(0, 0, a, :gray90)
   θ = atand(a/2, a + a√3/2)  # 15°
   for i = 90:60:390
       plot!([R*cosd(i-θ), R*cosd(i+θ), a*cosd(i+2θ), a*cosd(i-2θ), R*cosd(i-θ)],
             [R*sind(i-θ), R*sind(i+θ), a*sind(i+2θ), a*sind(i-2θ), R*sind(i-θ)],
             color=:blue, lw=0.5)
   end
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(a/2, a + a√3/2, "(a/2,a+a√3/2)", :red, :left, :bottom, delta=delta/2)
       point(a/2, a√3/2, " (a/2,a√3/2)", :blue, :left, :vcenter)
       point(0, R, " R", :red, :left, :bottom, delta=delta/2)
       point(0, a, " a", :red, :left, :bottom, delta=delta/2)
   end
end;

算額（その963）

算額（その963）

一七 大里郡岡部村岡 稲荷社 文化13年(1816)

埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.

長方形内に等円 3 個と大円 1 個が入っている。長方形の長辺が 260 寸のとき，短辺はいかほどか。

長辺，短辺をそれぞれ a, b
大円の半径と中心座標を r1, (x1, 3r2); r1 = 3r2 = b/2
等円の半径と中心座標を r2, (r2, r2), (r2, 3r2), (r2, 5r2); r2 = b/6
とおき，以下の方程式を解く。

include("julia-source.txt");

using SymPy
@syms a::positive, b::positive,
     r1::positive, x1::positive, r2::positive
r2 = b/6
r1 = b/2
x1 = a - r1
eq1 = (x1 - r2)^2 + 4r2^2 - (r1 + r2)^2
res = solve(eq1, b)[1]
res |> println
res(a => 260).evalf() |> println

   3*a*(2 - sqrt(3))
   209.000370096276

短辺は長辺の 3(2 - √3) 倍である。
長辺が 260 寸のとき，短辺は 260*3(2 - √3) = 209.000370096276 寸である。

function draw(more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   a = 260
   b = 3*a*(2 - sqrt(3))
   r2 = b/6
   r1 = b/2
   x1 = a - r1
   @printf("長辺が %g のとき，短辺は %g\n", a, b)
   plot([0, a, a, 0, 0], [0, 0, b, b, 0], color=:blue, lw=0.5)
   circle(r2, r2, r2)
   circle(r2, 3r2, r2)
   circle(r2, 5r2, r2)
   circle(x1, 3r2, r1, :green)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:black, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(x1, r1, "大円:r1,(x1,r1)", :green, :center, delta=-delta/2)
       point(r2, r2, "等円:r2,(r2,r2)", :red, :center, delta=-delta/2)
       point(r2, 3r2, "等円:r2\n(r2,3r2)", :red, :center, delta=-delta/2)
       point(r2, 5r2, "等円:r2,(r2,5r2)", :red, :center, delta=-delta/2)
       point(a, 0, " a", :blue, :left, :bottom, delta=delta/2)
       point(0, b, " b", :blue, :left, :bottom, delta=delta/2)
   end
end;