算額（その1165）

算額（その1165）

六四 加須市不動岡 総願寺 慶応2年(1866)
埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.
キーワード：円5個，楕円，斜線2本

楕円の中に斜線を 2 本引き，甲円 1 個，乙円 2 個，丙円 2 個を容れる。甲円の直径が 1 寸のとき，丙円の直径はいかほどか。

『埼玉の算額』の図では乙円が楕円と 2 点で接しているように描かれているが，乙円は曲率円であり，楕円の端点と 1 点で接するものである。

楕円の中心を原点とする。
甲円の半径（楕円の短半径）を r1
楕円の長半径を a
乙円の半径と中心座標を r2, (a - r2, 0)
丙円の半径と中心座標を r3, (a - 2r2 - r3, 0)
斜線と楕円の交点座標を (x0, y0)
とおき，以下の連立方程式を解く。
(x0, y0) は図を描くためだけに必要なので，r3 を求めるだけなら eq1, eq2, eq3 の三元連立方程式を解くだけでよい。

include("julia-source.txt");

using SymPy
@syms r1::positive, r2::positive, r3::positive, a::positive, x0::positive, y0::positive
eq1 = r2 - r1^2/a
eq2 = r2 - (a - r1)/2
eq3 = r3/(r1- r3) - r2/(a - r2)
eq4 = x0^2/a^2 + y0^2/r1^2 - 1
eq5 = dist2(0, 0, x0, y0, a - r2, 0, r2);

res = solve([eq1, eq2, eq3], (r3, r2, a))[1]

   (r1/4, r1/2, 2*r1)

res2 = solve([eq1, eq2, eq3, eq4, eq5], (r3, r2, a, x0, y0))[1]

   (r1/4, r1/2, 2*r1, 2*sqrt(6)*r1/3, sqrt(3)*r1/3)

丙円の半径 r3 は甲円の半径の 1/4 である。ちなみに，乙円の半径 r2 は甲円の半径の 1/2 である。
甲円の直径が 1 寸のとき，丙円の直径は 2 分 5 厘，乙円の直径は 5　分である。

その他のパラメータは以下のとおりである。

  r1 = 0.5;  r3 = 0.125;  r2 = 0.25;  a = 1;; x0 = 0.816497;  y0 = 0.288675

function draw(r1, more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   (r3, r2, a, x0, y0) = (r1/4, r1/2, 2*r1, 2*sqrt(6)*r1/3, sqrt(3)*r1/3)
   @printf("甲円の直径が %g のとき，丙円の直径は %g，乙円の直径は %g である。\n", 2r1, 2r3, 2r2)
   @printf("r1 = %g;  r3 = %g;  r2 = %g;  a = %g;; x0 = %g;  y0 = %g\n", r1, r3, r2, a, x0, y0)
   plot()
   ellipse(0, 0, a, r1, color=:red)
   circle(0, 0, r1, :orange)
   circle2(a - r2, 0, r2, :blue)
   circle2(r1 - r3, 0, r3, :green)
   segment(-x0, -y0, x0, y0, :magenta)
   segment(-x0, y0, x0, -y0, :magenta)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:gray80, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(0, r1, " r1", :red, :left, :bottom, delta=delta/2)
       point(a, 0, " a", :red, :left, :bottom, delta=delta/2)
       point(a - r2, 0, "乙円:r2\n(a-r2,0)", :blue, :center, delta=-2delta)
       point(r1 - r3, 0, "丙円:r3\n(r1-r3,0)", :black, :center, delta=-2delta)
       point(x0, y0, "(x0,y0)  ", :magenta, :right, :vcenter)
   end
end;

算額（その1164）

算額（その1164）

九八 鴻巣市三ツ木山王 三木神社 明治28年(1895)
埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.
キーワード：円1個，楕円2個，正六角形

正六角形の中に，交差する 2 個の半楕円と，楕円に内接する円を容れる。円の直径が 1 寸のとき，正六角形の一辺の長さはいかほどか。

片方の楕円（赤で描いたもの）の長軸が x 軸上にあるように，算額の図を反時計回りに 60° 回転させて考える。もう一つの楕円（灰色で描いたもの）は考えなくてもよい。

正六角形の中心を原点とする
正六角形の一辺の長さを s
楕円の長半径，短半径 を a, b
楕円と正六角形の辺との接点座標を (x, 0)
内接円の半径を r
とおく。
x = s*cos(π/6)
a = 2x
b = s/2
である。

楕円と内接円に関する算法助術の公式84を解き，正六角形の一辺の長さを求める。

include("julia-source.txt");

using SymPy
@syms s, r, a, b
x = s*cosd(Sym(30))
a = 2x
b = s/2
eq1 = x^2 - (a^2 - b^2)*(b^2 - r^2)/b^2
ans_s = solve(eq1, s)[2];

正六角形の一辺の長さは，内接円の半径の √22/2 倍である（直径の √22/4 倍）。
内接円の直径が 1 寸のとき，正六角形の一辺の長さは √22/4 = 1.1726039399558574 寸である。

ans_s |> println
ans_s(r => 1/2).evalf() |> println

   sqrt(22)*r/2
   1.17260393995586

function draw(r, more=false)
   pyplot(size=(500, 500), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   s = √22r/2
   (x, y) = s.*(cosd(30), sind(30))
   (a, b) = (2x, s/2)
   plot([0, -x, -x, 0, x, x, 0], [s, y, -y, -s, -y, y, s], color=:blue, lw=0.5)
   circle(0, 0, r, :green)
   circle(-2x, 0, r, :gray70)
   ellipse(-x, 0, a, b, color=:red)
   ellipse(-x/2, s - y/2, a, b, φ=-60, color=:gray70)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:gray80, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(-x, 0, "楕円:a,b,(-x,0)", :red, :center, delta=-delta/2)
       point(r, 0, "r ", :green, :right, :bottom, delta=delta/2)
       point(x, y, "(x,y) ", :blue, :right, delta=-delta/2)
       point(-2x, 0, "-2x", :gray70, :center, delta=-delta/2)
       point(x, 0, " x", :red, :left, :bottom, delta=delta/2)
       point(0, s, " s", :red, :left, :bottom, delta=delta/2)
       point(0, 0, " 0", :black, :left, :bottom, delta=delta/2)
   end
end;

算額（その1163）

算額（その1163）

六四 加須市不動岡 総願寺 慶応2年(1866)
埼玉県立図書館：埼玉県史料集 第二集『埼玉の算額』，昭和44年，誠美堂印刷所，埼玉県与野市.
キーワード：楕円，長方形，円，正方形，斜線4本

長方形の中に頂点と辺の中点を結ぶ 4 本の斜線を引き，区画された領域の一つに楕円を容れる。楕円の短径が 1 寸のとき，長方形の短辺の長さはいかほどか。

楕円は円を引き伸ばし（引き縮め）たものである。提示された図の長方形の横幅を縮め，縦横比が 1:1 すなわち正方形になったとき楕円は円になる。

縦方向の比率は変わらないので，円の直径から正方形の一辺を求める問題になる。直角三角形の 3 辺とそれに内接する円の直径の関係式を解けば，正方形の一辺の長さがわかる。

長方形の短辺の長さを a，楕円の短半径を r として，以下の方程式を解く。
注：短径は「短半径の2倍」である。

include("julia-source.txt");

using SymPy
@syms a, r
eq = a + a/2 - sqrt(a^2 + a^2/4) - 2r
res = solve(eq, a)[2]  # 2 of 2
res |> println
res(r => 1/2).evalf() |> println

   r*(sqrt(5) + 3)
   2.61803398874989

長方形の短辺の長さ a は，楕円の短半径 r の (√5 + 3) 倍 である。
楕円の短径が 1 寸のとき，長方形の短辺の長さは 2.61803398874989 寸である。

function draw(倍率, more=false)
   pyplot(size=(倍率*400, 400), grid=false, aspectratio=1, label="", fontfamily="IPAMincho")
   r = 1/2
   a = r*(√5 + 3)
   plot(倍率.*[0, a, a, 0, 0], [0, 0, a, a, 0], color=:blue, lw=0.5)
   plot!(倍率.*[0, a/2, a], [a, 0, a], color=:green, lw=0.5)
   plot!(倍率.*[a, 0, a], [a, a/2, 0], color=:green, lw=0.5)
   ellipse(倍率*r, r, 倍率*r, r, color=:red)
   if more        
       delta = (fontheight = (ylims()[2]- ylims()[1]) / 500 * 10 * 2) /3  # size[2] * fontsize * 2
       hline!([0], color=:gray80, lw=0.5)
       vline!([0], color=:gray80, lw=0.5)
       point(0, a, " a", :blue, :left, :bottom, delta=delta/2)
       point(倍率*r, r, "(倍率*r,r)", :red, :center, delta=-delta/2)
       point(倍率*a, 0, "(倍率*a,0)", :blue, :center, delta=-delta/2)
       point(倍率*a/2, 0.9a, @sprintf("倍率 = %g", 倍率), :black, :center, mark=false)
       plot!(ylims=(-8delta, a + 5delta), xlims=(-8delta, 倍率*a + 15delta))
   end
end;