ArduinoでRC可動戦車（2）スケッチ

ArduinoでRC可動戦車（2）のスケッチが、上手く動かないとの事で、
確認したところ、一部が欠落していました。
訂正しても、上手く書き換わってくれないので、こちらに改めて表記しました。

 

 

// PS3BT_arduino_battle_tank_2dcmotor
#include <AFMotor.h>
#include <PS3BT.h>
#include <usbhub.h>
#ifdef dobogusinclude
#include <spi4teensy3.h>
#endif

USB Usb;
BTD Btd(&Usb); //そうしたBluetooth Dongleの事例を作成する必要があります
PS3BT PS3(&Btd); //これで事例が作成されます
//PS3BT PS3(&Btd, 0x00, 0x15, 0x83, 0x3D, 0x0A, 0x57);
// これにはBluetoothアドレスも格納されます
// これはスケッチを実行するときにドングルから取得できます

//モーターシールドの3,4のモーターを使用する
AF_DCMotor motor3(3, MOTOR12_64KHZ); //右側モータ
AF_DCMotor motor4(4, MOTOR12_64KHZ); //左側モータ

int pos_y;
int pos_x;
int motor_sp;
const int motor_sp1 = 128; //超信地旋回速度
const int motor_sp0 = 0; //超低速

void setup() {
  Usb.Init();
  Serial.begin(115200);
  while (!Serial); // シリアルポートが接続するのを待つ
  if (Usb.Init() == -1) {
    Serial.print(F("\r\nOSC did not start"));
    while (1); //halt
  }
  Serial.print(F("\r\nPS3 Bluetooth Library Started"));

  motor3.run(RELEASE);
  motor4.run(RELEASE);
}

void loop() {
  Usb.Task();
  if (PS3.PS3Connected) {
    //スティックの中央は127だけどピタリと止まらないので+-10ほど余裕を持たせる。
    //左スティック上下の値(最上部0、中央127、最下部255)を読み込む
    pos_y = PS3.getAnalogHat(LeftHatY);
    pos_x = PS3.getAnalogHat(LeftHatX);

    //左スティックがセンター付近は停止
    if (pos_x >= 117 && pos_x <= 137 && pos_y >= 117 && pos_y <= 137) {
      motor3.setSpeed(0);
      motor3.run(RELEASE);
      motor4.setSpeed(0);
      motor4.run(RELEASE);
    }

    //前進
    else if (pos_y < 117 && pos_x > 117 && pos_x < 137) {
      //左スティック中央(127)から最上部(0)の値をモーターのスピード0から255に変換
      motor_sp = map(pos_y, 137, 0, 0, 255);
      motor3.setSpeed(motor_sp);
      motor3.run(FORWARD);
      motor4.setSpeed(motor_sp);
      motor4.run(FORWARD);
    }

    //後進
    else if ( pos_y > 137 && pos_x > 117 && pos_x < 137) {
      motor_sp = map(pos_y, 137, 255, 0, 255);
      motor3.setSpeed(motor_sp);
      motor3.run(BACKWARD);
      motor4.setSpeed(motor_sp);
      motor4.run(BACKWARD);
    }

    //前進右旋回
    else if ( pos_y < 117 && pos_x > 137) {
      motor_sp = map(pos_y, 117, 0, 0, 255);
      motor3.setSpeed(motor_sp0);
      motor3.run(FORWARD);
      motor4.setSpeed(motor_sp);
      motor4.run(FORWARD);
    }

    //前進左旋回
    else if ( pos_y < 117 && pos_x < 117) {
      motor_sp = map(pos_y, 117, 0, 0, 255);
      motor3.setSpeed(motor_sp);
      motor3.run(FORWARD);
      motor4.setSpeed(motor_sp0);
      motor4.run(FORWARD);
    }

    //後進右旋回
    else if ( pos_y > 137 && pos_x > 137) {
      motor_sp = map(pos_y, 137, 255, 0, 255);
      motor3.setSpeed(motor_sp0);
      motor3.run(BACKWARD);
      motor4.setSpeed(motor_sp);
      motor4.run(BACKWARD);
    }

    //後進左旋回
    else if ( pos_y > 137 && pos_x < 117) {
      motor_sp = map(pos_y, 117, 0, 0, 255);
      motor3.setSpeed(motor_sp);
      motor3.run(BACKWARD);
      motor4.setSpeed(motor_sp0);
      motor4.run(BACKWARD);
    }

    //右超信地旋回
    else if ( pos_y > 117 && pos_y < 137 && pos_x > 137) {

      motor3.setSpeed(motor_sp1);
      motor3.run(BACKWARD);
      motor4.setSpeed(motor_sp1);
      motor4.run(FORWARD);
    }

    //左超信地旋回
    else if ( pos_y > 117 && pos_y < 137 && pos_x < 117) {

      motor3.setSpeed(motor_sp1);
      motor3.run(FORWARD);
      motor4.setSpeed(motor_sp1);
      motor4.run(BACKWARD);
    }
  }
}