RC可動 1/35 メルカバMk.1 プログラム

2022-09-29 10:43:50 | 1/35 メルカバmk1

 /*PS3_ESP32_tank_JQ6500mp3_DRV8835_merkava_v7.0
  2022-09-29
  【操作方法】
  PS3コントローラで操縦します。
  車体の電源をONし、コントローラのPSボタンでペアリング開始。
  インジケータランプ4個高速点滅後に1個点灯でペアリング完了。

  コントローラーの左スティック上下で前後進、右スティックの左右でステアリングを制御。
  ステアリングを切っていくと緩旋回、一杯切るとで信地旋回する。
  また、左スティック中央でステアリング左右一杯で超信地旋回。

  △ボタンで砲身UP、?ボタンで砲身DOWN、□ボタンでセンター位置になる。
  左スティック左右で砲塔旋回。離した位置で止まる。

  R1ボタンで主砲発射。L1ボタンで機銃射撃。
  RIGHTボタンでヘッドライト点灯、LEFTボタンで消灯。
  R2ボタンで右超信地旋回 + 砲塔左旋回　＝　疑似砲塔追尾デモ
  L2ボタンで左超信地旋回 + 砲塔右旋回　＝　疑似砲塔追尾デモ
  //SQUAREボタンで疑似砲塔追尾でも終了

  砲撃時のリコイルアクション車体+砲身

  メインCPU：　　ESP32 DevKitC
  ボード　：　ESP32 Dev Module
  モータドライバ:DRV8835
  MP3プレイヤー：JQ6500 MP3プレイヤーモジュール
*/

#include <Arduino.h>
#include <JQ6500_Serial.h>
HardwareSerial Serial_df(2); //16pin=RX, 17pin=TX
JQ6500_Serial mp3(Serial_df);
void printDetail(uint8_t type, int value);
#include <Ps3Controller.h>

#include <ESP32Servo.h>
Servo servo1;
int servo1Pin = 27;
Servo servo2;
int servo2Pin = 14;
Servo servo3;
int servo3Pin = 12;

int LED_1 = 23; //ブレーキランプ
int LED_2 = 22; //ヘッドライト
int LED_3 = 19; //砲撃
int LED_4 = 18; //銃撃

int k = 0;
int s = 0;
int d_time = 30;

int angle_servo1 = 90; // 上下
int anglenow = angle_servo1 ;
int angle_servo3 = 90; //　リコイル
int motor_speed;
float steering;
int pos_y;
int pos_x;
int pos_lx;

int AIN1 = 32;
int BIN1 = 25;
int PWMApin = 33;
int PWMBpin = 26;
int PWMA = 2;
int PWMB = 3;
int cnt = 0;

void setup() {
  servo1.setPeriodHertz(50);
  servo1.attach(servo1Pin, 500, 2400);
  servo2.setPeriodHertz(50);
  servo2.attach(servo2Pin, 900, 2100);
  servo3.setPeriodHertz(50);
  servo3.attach(servo3Pin, 500, 2400);

  Serial.begin(115200);
  //mySoftwareSerial.begin(9600);
  Serial_df.begin(9600); // RX2 = 16, TX2 = 17
  mp3.reset();
  mp3.setVolume(25);

Ps3.begin("00:11:22:33:44:55"); //SixaxisPairToolで調べたmac adresに修正
  Serial.println("PS3 Ready");

  ledcSetup(PWMA, 12000, 8);
  ledcAttachPin(PWMApin, PWMA);
  ledcSetup(PWMB, 12000, 8);
  ledcAttachPin(PWMBpin, PWMB);
  pinMode(AIN1, OUTPUT);
  pinMode(BIN1, OUTPUT);
  pinMode(LED_1, OUTPUT);
  pinMode(LED_2, OUTPUT);
  pinMode(LED_3, OUTPUT);
  pinMode(LED_4, OUTPUT);

  LEDtenmetsu(LED_2);

  servo1.write(angle_servo1); // CENTER
  delay(50);
  servo2.write(90); // STOP
  delay(50);
  servo3.write(angle_servo3); // 仰角0°
  delay(50);

  //myDFPlayer.play(3); //エンジン始動
  mp3.playFileByIndexNumber(3);
  delay(500);

}

void loop() {

  if (Ps3.isConnected()) {
    pos_lx = Ps3.data.analog.stick.lx;
    pos_lx = pos_lx + 128;

    //砲塔旋回
    if ( pos_lx > 230) { //右旋回
      mp3.playFileByIndexNumber(31);
      servo2.write(76);
      //delay(50);
    } else if (pos_lx < 25) { //左旋回
      mp3.playFileByIndexNumber(31);
      servo2.write(104);
      //delay(50);
    } else { //停止
      servo2.write(90);
    }

    //砲身上下
    if ( Ps3.event.button_down.square) { // center
      if (anglenow > angle_servo1) {
        for (anglenow = anglenow; anglenow >= angle_servo1; anglenow -= 1) {
          servo1.write(anglenow);
          delay(40);
        }
        //delay(100);
      }
      else {
        for (anglenow = anglenow; anglenow <= angle_servo1; anglenow += 1) {
          servo1.write(anglenow);
          delay(40);
        }
        //delay(100);
      }
    }

    if ( Ps3.event.button_down.cross) { // down
      for (anglenow = anglenow; anglenow <= (angle_servo1 + 15); anglenow += 1 ) {
        servo1.write(anglenow);
        delay(40);
      }
      //delay(100);
    }

    if ( Ps3.event.button_down.triangle) { // up
      for (anglenow = anglenow; anglenow >= (angle_servo1 - 40); anglenow -= 1 ) {
        servo1.write(anglenow);
        delay(40);
      }
      //delay(100);
    }

    if (Ps3.event.button_down.circle) {
      if (s == 0) {
        s = 1;
        //myDFPlayer.play(3); //エンジン始動
        mp3.playFileByIndexNumber(3);
        delay(1000);
        //myDFPlayer.loop(5); //Loop 5th mp3 アイドリング
        mp3.playFileByIndexNumber(5);
        mp3.setLoopMode(MP3_LOOP_ONE);
        delay(d_time);
      } else {
        //myDFPlayer.disableLoop(); //アイドリング停止
        mp3.pause();
        mp3.setLoopMode(MP3_LOOP_ONE_STOP);
        s = 0;
        delay(100);
      }
    }

    if (Ps3.event.button_down.r3) {
      //myDFPlayer.disableLoop(); //アイドリング停止
      mp3.pause();
      mp3.setLoopMode(MP3_LOOP_ONE_STOP);
      s = 0;
    }

    if (Ps3.event.button_down.right) {
      digitalWrite(LED_2, HIGH); // ヘッドライト ON
    }

    if (Ps3.event.button_down.left) {
      digitalWrite(LED_2, LOW); // ヘッドライト off
    }

    if (Ps3.data.button.r2) { //右超信地旋回疑似砲塔追尾デモ
      servo2.write(104); //砲塔左旋回
      motor_speed = 165;
      motor_run(motor_speed, 0, motor_speed, 1, 0);
      delay(500);
    }

    if (Ps3.data.button.l2) { //左超信地旋回疑似砲塔追尾デモ
      servo2.write(76); //砲塔右旋回
      motor_speed = 165;
      motor_run(motor_speed, 1, motor_speed, 0, 0);
      delay(500);
    }

    if (Ps3.event.button_down.r1) { //砲撃 + リコイル（砲身＆車体）
      digitalWrite(LED_3, HIGH); //主砲発光
      //mp3.playFileByIndexNumber(14);
      mp3.playFileByIndexNumber(2);
      delay(50);
      digitalWrite(LED_3, LOW);
      servo3.write(angle_servo3 + 40); // 砲身リコイル
      delay(20);
      motor_run(180, 1, 180, 1, 1); //　車体リコイル
      //digitalWrite(LED_3, LOW);
      delay(60);
      motor_run(0, 0, 0, 0, 1);
      // digitalWrite(LED_3, LOW);
      for (int ang3 = (angle_servo3 + 50); ang3 >= angle_servo3; ang3 -= 1 ) {
        servo3.write(ang3);
        delay(15);
      }
      //digitalWrite(LED_3, LOW);
      motor_run(100, 0, 100, 0, 1);
      delay(80);
      motor_run(0, 0, 0, 0, 1);
      delay(100);
      if (s == 1) {
        //myDFPlayer.loop(5); //Loop 5th mp3 アイドリング
        mp3.playFileByIndexNumber(5);
        mp3.setLoopMode(MP3_LOOP_ONE);
        delay(d_time);
      }
    }

    if (Ps3.event.button_down.l1) { //銃撃
      //myDFPlayer.play(24);
      mp3.playFileByIndexNumber(24);
      //delay(20);
      for ( k = 0; k < 6; k++) {
        digitalWrite(LED_4, HIGH); //発光
        delay(80);
        digitalWrite(LED_4, LOW);
        delay(120);
      }
      if (s == 1) {
        //myDFPlayer.loop(5); //Loop 5th mp3 アイドリング
        mp3.playFileByIndexNumber(5);
        mp3.setLoopMode(MP3_LOOP_ONE);
        delay(d_time);
      }
    }

    //走行コントロール
    pos_y = Ps3.data.analog.stick.ly;
    pos_x = Ps3.data.analog.stick.rx;
    pos_y = pos_y + 128;
    pos_x = pos_x + 128;

    /* //左スティックがセンター付近は停止（ブレーキ）
        if (pos_x > 102 && pos_x < 152 && pos_y > 102 && pos_y < 152) {
          motor_run(0, 0, 0, 0, 1);
        }
    */

    //前進
    if (pos_y <= 102 && pos_x >= 102 && pos_x <= 152) {
      motor_speed = map(pos_y, 102, 0, 0, 255);
      motor_run(motor_speed, 0, motor_speed, 0, 0);
    }

    //後進
    else if ( pos_y >= 152 && pos_x >= 102 && pos_x <= 152) {
      motor_speed = map(pos_y, 152, 255, 0, 255) ;
      motor_run(motor_speed, 1, motor_speed, 1, 0);
    }

    //前進右緩旋回、信地旋回
    //else if ( pos_y <= 102 && pos_x > 152 && pos_x <= 245) {
    else if ( pos_y <= 102 && pos_x >= 152) {
      motor_speed = map(pos_y, 102, 0, 0, 255);
      steering = motor_speed * (1.00 - (map(pos_x, 152, 255, 0, 255) / 255.00));
      motor_run(motor_speed, 0, steering, 0, 0);
    }

    //前進左緩旋回、信地旋回
    //else if ( pos_y <= 102 && pos_x < 102 && pos_x >= 10) {
    else if ( pos_y <= 102 && pos_x <= 102) {
      motor_speed = map(pos_y, 102, 0, 0, 255);
      steering = motor_speed * (1.00 - (map(pos_x, 102, 0, 0, 255) / 255.00));
      motor_run(steering, 0, motor_speed, 0, 0);
    }

    //後進右緩旋回、信地旋回
    //else if ( pos_y >= 152 && pos_x > 152 && pos_x <= 245) {
    else if ( pos_y >= 152 && pos_x >= 152 ) {
      motor_speed = map(pos_y, 152, 255, 0, 255);
      steering = motor_speed * (1.00 - (map(pos_x, 152, 255, 0, 255) / 255.00));
      motor_run(motor_speed, 1, steering, 1, 0);
    }

    //後進左緩旋回、信地旋回
    //else if ( pos_y >= 152 && pos_x < 102 && pos_x >= 10) {
    else if ( pos_y >= 152 && pos_x <= 102 ) {
      motor_speed = map(pos_y, 152, 255, 0, 255);
      steering = motor_speed * (1.00 - (map(pos_x, 102, 0, 0, 255) / 255.00));
      motor_run(steering, 1, motor_speed, 1, 0);
    }

    //右超信地旋回
    else if (pos_x >= 245 && pos_y >= 102 && pos_y <= 152) {
      motor_speed = 165;
      motor_run(motor_speed, 0, motor_speed, 1, 0);
    }

    //左超信地旋回
    else if (pos_x <= 10 && pos_y >= 102 && pos_y <= 152) {
      motor_speed = 165;
      motor_run(motor_speed, 1, motor_speed, 0, 0);
    }

    else { //停止（ブレーキ）
      motor_run(0, 0, 0, 0, 1);
    }
  }
}


void motor_run(int D0, int D1, int D2, int D3, int D4) {
  //D0 : モータスピード（左）
  //D1 : モータA（左）1 = HIGH / 0 = LOW
  //D2 : モータスピード（右）
  //D3 : モータB（右）1 = HIGH / 0 = LOW
  //D4 : LED_3 ON/OFF 1 = HIGH / 0 = LOW

  //analogWrite(PWMA, D0);
  ledcWrite(PWMA, D0); //(チャンネル,解像度)
  digitalWrite(AIN1, D1);
  //analogWrite(PWMB, D2);
  ledcWrite(PWMB, D2); //(チャンネル,解像度)
  digitalWrite(BIN1, D3);
  digitalWrite(LED_1, D4);
}

void LEDtenmetsu(int LED) {
  for (int i = 0; i < 2; i++) {
    digitalWrite(LED, HIGH);
    delay(500);
    digitalWrite(LED, LOW);
    delay(500);
  }
}

コメントを投稿

プロフィール

自己紹介: 模型作り、ドライブ、DIYなどを楽しんでいます。
▼Youtubeもよろしく。
https://www.youtube.com/@ganpon

ブックマーク

ワイのもじけたブログやで～: 模型作りや旅行記、日々の出来事など気ままに紹介しています。
はじめの戦車模型づくり: 老眼に悩みながらもとにかく完成させることを目指します！
ウォーターライン　こちら艦プラ生活広報課: みんなで楽しむプラモデル！おじさん艦隊発進！！
ムライ博士の異常な愛情: 〜私は如何にして散財し将来を心配するのを止めて、フィギュアや模型を愛するようになったか〜
Junky Monologue: ハンドメイドスピーカー、お気に入りの音楽、プラモその他趣味の話。
パンツァーごー: 猫さんと賭け事と時々プラモデル
最初はgoo

アクセス状況

アクセス
閲覧	1,093	PV
訪問者	617	IP
トータル
閲覧	2,136,470	PV
訪問者	1,070,814	IP
ランキング
日別	1,046	位
週別	1,791	位

goo blog お知らせ

	ブログを読むだけ。毎月の訪問日数に応じてポイント進呈
	【コメント募集中】一番好きな「クリスマスソング」は？
	訪問者数に応じてdポイント最大1,000pt当たる！
	dポイントが当たる！無料『毎日くじ』